[Procedural Programming + Ada] Bài 15 – Console Tic-Tac-Toe App (tiếp theo)

Những dữ liệu trạng thái mà chúng ta cần quản lý trong phần model bao gồm các tập giá trị thể hiện các bước đi của User và Computer, và các ô trống còn lại trên bảng. Thêm vào đó, một loại dữ liệu trạng thái khác cũng rất cần thiết là Match_Status thể hiện trạng thái hiện tại của ván cờ là đang tiếp tục hay đã kết thúc với kết quả nào đó.

App_State

Để lưu trữ các tập giá trị thể hiện các bước đi đã thực hiện của User và Computer, và các ô trống còn lại trên bảng thì phù hợp nhất có lẽ là cấu trúc Set như đã biết trong Sub-Series về JavaScript. Bởi chúng ta sẽ có thể đảm bảo rằng ít nhất thì các giá trị trong mỗi Set sẽ không bị lặp lại và là duy nhất.

So với C thì thư viện tiêu chuẩn của Ada rộng hơn khá nhiều và có thêm các cấu trúc dữ liệu phổ biến trong chủ đề DSA, chỉ thiếu duy nhất Stack. Hiển nhiên với một vế with .. use thì chúng ta sẽ có thể sử dụng Set thay cho các Array tự định nghĩa để giải quyết tình huống.

Tuy nhiên, mục đích của mình khi tạo project này là luyện tập một chút về khả năng tự định nghĩa kiểu dữ liệu và sử dụng các công cụ tạo ràng buộc như subtype và contract; Vì vậy nên…

package App_Model is
   subtype Digit is Integer range 0 .. 9;
   type Digit_Array is array (1 .. 9) of Digit;
   type Status is (PLAYING, DRAW, USER_WIN, COMPUTER_WIN);

   type State is record
      Common_Set : Digit_Array;
      User_Set : Digit_Array;
      Computer_Set : Digit_Array;
      Match_Status : Status;
   end record;
end App_Model;

Chúng ta đang có định nghĩa trọng tâm là type State với các thành phần bao gồm:

• Common_Set – Các ô trống còn lại trên bảng
• User_Set – Các ô mà User đã đánh dấu
• Computer_Set – Các ô mà Computer đã đánh dấu
• Match_Status – Trạng thái hiện tại của ván cờ

Quy ước được sử dụng ở đây là các tập dữ liệu *_Set sẽ lưu các giá trị số học có ý nghĩa là 1 .. 9 biểu thị cho các ô trên bảng Tic-Tac-Toe. Và giá trị 0 được sử dụng làm giá trị vô nghĩa và không biểu thị cho ô nào trên bảng. Như vậy khởi điểm mỗi ván cờ chúng ta sẽ có Common_Set chứa đầy đủ các giá trị 1 .. 9, còn User_Set và Computer_Set sẽ chứa các giá trị 0.

Kiểu trạng thái type Status thể hiện các trạng thái của ván cờ được liệt kê với tuần tự là: Đang Tiếp Diễn.. Kết Quả Hòa.. Người Dùng Thằng.. và Máy Tính thắng.

Init_App_State;

Khi khai báo một biến cục bộ App_State : State thì về căn bản là biến này đã được phân bổ một vùng bộ nhớ dành cho record với các trường dữ liệu chưa được khởi tạo giá trị có nghĩa. Vì vậy nên giống với thao tác Get_User_Symbol;, ở đây thao tác Init_App_State; như dự kiến lúc đầu có thể được định nghĩa với cú pháp sử dụng là procedure hoặc function:

-- procedure
Init (App_State);

-- function
App_State := App_Model.Init;

Bạn có thể chọn phương thức phù hợp với phong cách tư duy của bạn. Còn ở đây thì mình chọn procedure để phù hợp với tinh thần của Sub-Series này.

package App_Model is
   -- subtype Digit is ...

   -- type State is ...

   procedure Init (App_State : out State);
end App_Model;

package body App_Model is

   procedure Init (App_State : out State) is
      -- local
   begin
      App_State :=
         ( Common_Set => (1, 2, 3, 4, 5, 6, 7, 8, 9)
         , User_Set => (others => 0)
         , Computer_Set => (others => 0)
         , Match_Status => PLAYING )
      ; -- App_State
   end Init;

end App_Model;

Trong code sử dụng tại Main, chúng ta sẽ tạm thời thêm lệnh in thử App_State để kiểm tra hoạt động của Init (App_State);.

with Ada.Text_IO; use Ada.Text_IO;
with App_Model; use App_Model;
with Console_IO; use Console_IO;

procedure Main is
   User_Symbol : Symbol;
   App_State : State;
begin
   Put_Symbol_Menu;
   Get (User_Symbol);

   Init (App_State);
   Put_Line (State'Image (App_State));
   -- 4. Put_Chess_Board;
   
   -- loop
      -- 5. Get_User_Move;
      -- 6. Update_User_Set;
      -- 7. Update_Match_Status;
      -- 8. Put_Chess_Board;
      --
      -- 9. Get_Computer_Move;
      -- 10. Update_Computer_Set;
      -- 11. Update_Match_Status;
      -- 12. Put_Chess_Board;
      --
      -- exit when App_State.Match_Status /= PLAYING;
   -- end loop
end Main;

Choose your Symbol ...
   1. Letter 'X'
   2. Letter 'O'
Your choice: 1
You've chosen: X

(COMMON_SET =>
 [ 1,  2,  3,  4,  5,  6,  7,  8,  9],
 USER_SET =>
 [ 0,  0,  0,  0,  0,  0,  0,  0,  0],
 COMPUTER_SET =>
 [ 0,  0,  0,  0,  0,  0,  0,  0,  0],
 MATCH_STATUS => PLAYING)

[Procedural Programming + Ada] Bài 16 – Console Tic-Tac-Toe App (tiếp theo)